La funzione SE in Excel: una spiegazione

La funzione SE-ALLORA è una delle più antiche e popolari funzioni di Excel. Il principio è molto semplice: se un valore è vero, allora si compie una determinata azione, altrimenti se ne fa un’altra. Ti spieghiamo come utilizzare correttamente la funzione SE-ALLORA e a cosa serve.

Che cos’è la funzione SE-ALLORA?

Con la funzione SE (questo è il nome corretto della formula) puoi effettuare un confronto logico: il valore richiesto è identico al valore atteso oppure no? Se lo è, allora segue un’azione. Se invece non lo è, l’azione viene sostituita da un’altra, cioè se A, allora B, se invece non A, allora C.

Ciò rende la funzione SE-ALLORA una delle più importanti di Excel. Questa funzione può essere utilizzata in tutte le situazioni possibili: sia che stai lavorando con un semplice elenco di membri, con un foglio di calcolo con dati chiave aziendali o con rapporti statistici, troverai questa funzione di grande aiuto, sia da sola che in combinazione con altre.

Come funziona la funzione SE-ALLORA di Excel?

Ogni funzione in Excel si basa su una sintassi specifica e lo stesso vale nel caso della funzione SE:

=SE(Verifica;allora_valore; altrimenti_valore)

La funzione contiene perciò tre parametri, di cui i primi due obbligatori.

• Verifica: in questa posizione bisogna specificare la condizione, un confronto tra due valori, uno o entrambi sotto forma di riferimenti a celle. Le condizioni possibili possono essere:

  • Uguale a =
  • Diverso da <>
  • Minore di <
  • Maggiore di >
  • Minore o uguale a <=
  • Maggiore o uguale a >=

• Allora_valore: in questo parametro si inserisce l’azione da compiere se la condizione è verificata. I risultati possono essere valori, stringhe, riferimenti di celle o altre funzioni. È necessario mettere le stringhe tra virgolette.

• Altrimenti_valore: l’ultimo parametro è opzionale. Se non si specifica nulla in questa posizione, viene restituita la funzione FALSO. In caso contrario, la condizione altrimenti_valore si comporta in modo analogo a quella allora_valore.

Nella pratica, una funzione SE-ALLORA in Excel potrebbe assomigliare a questa:

=SE(A1>=100;"Obiettivo raggiunto";"Obiettivo non ancora raggiunto")

Se lo desideri, puoi anche non inserire manualmente la funzione SE nella riga di inserimento: con “Inserisci funzione”, infatti, Excel ti offre la possibilità di aiutarti a compilare correttamente le formule.

La funzione SE-ALLORA chiarita con alcuni esempi

La funzione SE-ALLORA viene utilizzata in un’ampia varietà di situazioni, sia in fogli di calcolo semplici che molto complessi. Ti spieghiamo come funziona e ti illustriamo i suoi possibili utilizzi con cinque brevi esempi.

Ordinamento in base al punteggio

Se desideri dividere una serie di dati sotto forma di punteggio in percentuale in due gruppi in base a un criterio, puoi farlo con la funzione SE di Excel. Ad esempio, puoi verificare se una persona ha superato o meno un esame. Nell’esempio seguente, supera l’esame chi ha ottenuto un punteggio di almeno il 50%.

=SE(B2 >= 50%; "Superato"; "Non superato")

Controllo dei valori testuali

La funzione SE può essere utilizzata non solo per controllare valori numerici, ma anche valori testuali. L’esempio seguente verifica se un libro è stato scritto dall’autore “Stephen King”. La formula corrispondente è:

=SE(F2 = "Stephen King"; "Sì"; "No")

Concatenazione della funzione SE

A volte può accadere che sia necessario verificare un’ulteriore condizione dopo che la prima è stata superata o meno. In questi casi, è possibile specificare un’altra funzione SE-ALLORA invece di un “valore allora” o di un “valore altrimenti”. L’esempio seguente controlla se i pacchi sono già stati spediti.

=SE(J3="Consegnato";"Sì";SE(J3="In consegna"; "Sì";"No"))

Combinazione con altre funzioni

Come per la concatenazione di SE, anche altre funzioni di Excel possono essere utilizzate nei campi della formula SE. Tuttavia, le funzioni specificate come condizione della funzione SE devono sempre restituire come risultato “Vero” o “Falso”. L’esempio precedente è ricostruito di seguito utilizzando la funzione O di Excel.

=SE(O(N2="Consegnato";N2="In consegna");"Sì";"Falso")

Esempio più complesso

Per concludere, ti presentiamo un esempio leggermente più complesso. In questo esempio si tiene traccia del prezzo di un’azione e si indica se si è registrata una perdita o un aumento del suo valore. L’importo di questa perdita o dell’aumento viene calcolato e specificato. A tale scopo viene utilizzata la funzione CONCATENA di Excel.

=SE(R3<R2;CONCATENA("Perdita: "; R2-R3);CONCATENA("Guadagno: "; R3-R2))

PIÙ.SE: ampliamento di SE-ALLORA

Se utilizzi Microsoft 365, Office 2021, Office 2019 o Office Online, Excel ti offre un’altra funzione. La funzione PIÙ.SE funziona in modo simile alla funzione SE: a seguito di un controllo logico viene assegnato un allora_valore, ma fino a 127 volte. La sintassi è quindi la seguente:

=PIÙ.SE(Qualcosa è vero1; Valore quando è vero1; [Qualcosa è vero2; Valore quando è vero2];…[Qualcosa è vero127; Valore quando è vero127])

Ad esempio, si potrebbe offrire uno sconto sui prodotti di un negozio che sono rimasti invenduti a lungo. Questo esempio potrebbe essere ampliato riducendo ulteriormente il prezzo di quei prodotti già scontati e di cui ne rimangono pochi pezzi. In questo modo si verificherebbero due condizioni: sono passati più di 30 giorni dall’ultima vendita e non ci sono più di 10 articoli in magazzino. Dobbiamo quindi inserire un collegamento E nel primo parametro di controllo e definire altri casi, perché vogliamo che siano possibili tre risultati: 50 per cento di sconto, 25 per cento di sconto e nessuno sconto.

Ciò che si nota è che non c’è nessun altrimenti_valore. Questo significa anche che bisogna definire cosa accade nel caso opposto; nel nostro esempio nel caso in cui non vengano utilizzati sconti. La sintassi risulta quindi:

=PIÙ.SE(E(GIORNI(OGGI();Z2)>30;Y2<10);W2*0,5;GIORNI(OGGI();Z2)>30;W2*0,75;GIORNI(OGGI();Z2)<=30;W2)

Le verifiche di entrambi gli sconti vengono effettuate una dopo l’altra. Infine, segue il caso “altrimenti”: tutti i prodotti la cui ultima vendita risale a 30 giorni o meno.