Excel: utilizzare la funzione TROVA

Chi lavora molto con la suite di Microsoft Office sa bene quanto siano utili le numerose funzioni di Excel. Chi vorrebbe semplificarsi il lavoro con grandi raccolte di dati, dovrebbe conoscere la funzione TROVA.

Guida rapida: funzione TROVA di Excel

1. Seleziona una cella vuota qualsiasi nel tuo documento Excel.
2. Inserisci =TROVA(testo;stringa), indicando il testo da cercare come primo parametro e la cella o la stringa come secondo parametro.

Per quali compiti è utile la funzione TROVA di Excel?

Quando si lavora con grandi fogli di calcolo contenenti centinaia di celle, è facile perdere l’orientamento. Naturalmente anche Excel, come ogni altro prodotto Office, dispone di una funzione di ricerca integrata. Tuttavia, questa potrebbe non rispondere esattamente alle esigenze dell’utente, perché cerca automaticamente in tutto il documento.

Se desideri cercare all’interno di determinate celle e, inoltre, integrare la ricerca direttamente nel foglio di calcolo, puoi utilizzare la funzione TROVA.

Combina TROVA con altre funzioni per sfruttare appieno il potenziale di questa funzione. Puoi ad esempio sapere se un determinato termine è presente oppure estrarre parti specifiche da una stringa.

La sintassi della funzione TROVA di Excel

La sintassi di TROVA non è particolarmente complessa. Nella forma standard è necessario inserire soltanto due argomenti: cosa cerchi? E dove?

=TROVA(testo;stringa)

Puoi anche specificare ulteriormente la ricerca, indicando che deve iniziare da un determinato carattere:

=TROVA(testo;stringa;[inizio])

I parametri indicano diverse informazioni:

• Testo: la stringa che desideri cercare. Devi indicare il testo tra virgolette. Puoi anche fare riferimento a una cella in cui si trova il testo.
• Stringa: questo parametro definisce il testo in cui vuoi cercare. Nella maggior parte dei casi, qui indicherai una cella in cui si trova il testo. Tuttavia, in questa posizione è anche possibile inserire direttamente il testo. Anche in questo caso devi utilizzare le virgolette.
• Inizio: con un valore numerico stabilisci a partire da quale carattere deve iniziare la ricerca del testo da cercare. L’indicazione di questo valore è facoltativa.

Il risultato della ricerca viene fornito da Excel sotto forma di numero. Il valore numerico indica in quale posizione inizia il testo da cercare, vale a dire la prima occorrenza da sinistra.

Oltre alla funzione TROVA, Excel offre anche la funzione TROVA.B. Entrambe le funzioni forniscono lo stesso esito e sono assolutamente identiche anche nella sintassi. L’unica differenza consiste nel set di caratteri utilizzabile. TROVA funziona con le lingue basate sul cosiddetto set di caratteri a byte singolo (SBCS), tra le quali anche l’alfabeto latino (inclusi i caratteri speciali). Se, invece, si utilizzano caratteri asiatici di regioni quali la Cina, il Giappone e la Corea (CJK), è necessario utilizzare la funzione TROVA.B, che utilizza le lingue basate sul set di caratteri a byte doppio (DBCS).

Applicazione della funzione TROVA di Excel

La formula di Excel TROVA viene utilizzata principalmente in combinazione con altre funzioni, ed è qui che si rivela davvero utile.

TROVA e TROVA: annidamenti

Con un annidamento si può individuare la seconda, la terza o un’altra qualsiasi occorrenza del termine da cercare.

=TROVA(testo;stringa;TROVA(testo;stringa)+1)

Qui è possibile comprendere anche a cosa serve il terzo parametro opzionale. In questa formula, nella posizione “inizio” inseriamo nuovamente la formula che dà come risultato la posizione della prima occorrenza. Questo valore più uno indica a sua volta la posizione in cui la funzione sovraordinata deve iniziare la ricerca. Se desideri cercare anche una terza posizione, nidifica la funzione ancora una volta, e così via.

TROVA e VAL.NUMERO: proposizioni logiche

Con la funzione TROVA, Excel ha la possibilità, sulla base dell’indicazione della posizione, di formulare una proposizione logica: il termine cercato è presente o non è presente nel testo?

=VAL.NUMERO(TROVA("Orsetto di peluche";B2))

La funzione VAL.NUMERO fornisce il valore VERO se il risultato di TROVA è un numero, altrimenti compare FALSO. Poiché, con la funzione TROVA, Excel indica la posizione del termine in un numero intero, la funzione VAL.NUMERO può reagire alla richiesta. Se il termine cercato non è contenuto nel testo, TROVA fornisce un messaggio di errore, che non è un numero, e VAL.NUMERO restituisce di conseguenza FALSO.

Può inoltre essere interessante vedere dove sono collocati i termini cercati. È il caso, ad esempio, di un elenco di articoli venduti, in cui i dati sono stati inseriti in più celle. Come qualunque altra formula, anche questa può essere inserita nella cosiddetta formattazione condizionale. Questo ti permette ad esempio di evidenziare tutti gli ordini che hanno a che fare con orsetti di peluche.

TROVA e STRINGA.ESTRAI: estrazione dei caratteri

Le denominazioni degli articoli possono essere molto lunghe e difficili da interpretare, per questo potresti aver bisogno di estrarre determinati caratteri dalla stringa. A questo scopo Excel offre tre funzioni: SINISTRA, DESTRA e STRINGA.ESTRAI. Partiamo dal presupposto che le denominazioni dei tuoi articoli seguano sempre un determinato modello, composto da lettere, numeri e trattini: ABCDE-A-12345-T. Ciò che vuoi fare è estrarre la parte numerica contenuta all’interno della stringa.

Poiché, tuttavia, la stringa non possiede una lunghezza fissa, il risultato che vuoi ottenere non può essere raggiunto con semplici funzioni di estrazione. Tuttavia, grazie ai trattini, puoi aiutarti con la funzione TROVA. Questa, infatti, ti fornisce l’informazione sulla posizione di cui hai bisogno.

Poiché nella stringa sono contenuti più trattini, la funzione TROVA deve essere nidificata. In questo esempio ipotizziamo che la parte numerica sia sempre costituita da cinque caratteri:

=STRINGA.ESTRAI(A2;TROVA("-"; A2;TROVA("-"; A2;TROVA("-";A2)+1))+1;5)

Tuttavia, nel caso in cui la lunghezza della parte numerica non sia sempre uguale, è possibile ricorrere a un ulteriore annidamento delle funzioni TROVA. Poiché la sequenza desiderata termina con un trattino, è possibile cercare il trattino, determinando così la lunghezza.

=STRINGA.ESTRAI(A2;TROVA("-";A2;TROVA("-";A2;TROVA("-";A2)+1))+1; TROVA("-";A2;TROVA("-";A2;TROVA("-";A2)+1)+1)-TROVA("-";A2;TROVA("-";A2;TROVA("-";A2)-1))-3)

Sebbene questa formula sia particolarmente complessa, è di fatto in grado di fornire il risultato desiderato. Qualunque sia il numero di caratteri che inserisci tra i due trattini, con la formula TROVA Excel estrarrà sempre i caratteri corretti.

TROVA e SE: Se-Allora-Altrimenti

La funzione TROVA può essere combinata efficacemente anche con la funzione SE. Desideri eseguire un’azione se nella cella è presente una determinata stringa? La combinazione di SE e TROVA ti consente di farlo: se la stringa è presente, allora avviene questo, altrimenti quello. L’unico problema è che TROVA segnala un errore se la stringa non è presente. Per questo, è necessario utilizzare in aggiunta la funzione VAL.ERRORE.

=SE(VAL.ERRORE(TROVA("Orsetto di peluche";A2));"No";"Sì")

Se la funzione TROVA non rileva il termine cercato (in questo esempio “Orsetto di peluche”), genera un messaggio di errore. Per VAL.ERRORE, la condizione è soddisfatta e SE visualizza la prima opzione: no, il termine cercato non è presente. Se, invece, la funzione TROVA rileva il testo cercato, fornisce come risultato un numero che non soddisfa la condizione per VAL.ERRORE. In questo caso viene visualizzata l’alternativa: sì, il termine cercato è presente.